«Выплаты сотрудникам при использовании АУСН» для 1С:ЗУП

ВЫБРАТЬ РАЗРЕШЕННЫЕ РАЗЛИЧНЫЕ
	ПрименяемыеТарифыСтраховыхВзносов.ГоловнаяОрганизация КАК Организация,
	ПрименяемыеТарифыСтраховыхВзносов.ГоловнаяОрганизация.ИНН КАК ИНН
ПОМЕСТИТЬ ВТОрганизацииАУСН
ИЗ
	РегистрСведений.ПрименяемыеТарифыСтраховыхВзносов КАК ПрименяемыеТарифыСтраховыхВзносов
ГДЕ
	ПрименяемыеТарифыСтраховыхВзносов.ВидТарифа = ЗНАЧЕНИЕ(Справочник.ВидыТарифовСтраховыхВзносов.АУСН)
{ГДЕ
	ПрименяемыеТарифыСтраховыхВзносов.ГоловнаяОрганизация КАК Организация}
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ РАЗРЕШЕННЫЕ
	ДанныеУчета.Организация КАК Организация,
	ДанныеУчета.Период КАК Период,
	ДанныеУчета.ФизическоеЛицо КАК ФизическоеЛицо,
	ДанныеУчета.Начисление КАК Начисление,
	ДанныеУчета.ДокументНачисление КАК ДокументНачисление,
	СУММА(ДанныеУчета.СуммаДоходаНДФЛ) КАК СуммаДоходаНДФЛ,
	СУММА(ДанныеУчета.СуммаВычетаНДФЛ) КАК СуммаВычетаНДФЛ,
	СУММА(ДанныеУчета.СуммаВзносы) КАК СуммаВзносы,
	СУММА(ДанныеУчета.СкидкаВзносы) КАК СкидкаВзносы,
	ДанныеУчета.КодДохода КАК КодДохода,
	ДанныеУчета.КодВычета КАК КодВычета,
	ДанныеУчета.ВидДохода КАК ВидДохода,
	ДанныеУчета.ДатаПолученияДохода КАК ДатаПолученияДохода
ПОМЕСТИТЬ ВТДанныеУчета
ИЗ
	(ВЫБРАТЬ
		СведенияОДоходахНДФЛ.Организация КАК Организация,
		НАЧАЛОПЕРИОДА(СведенияОДоходахНДФЛ.ДатаПолученияДохода, МЕСЯЦ) КАК Период,
		СведенияОДоходахНДФЛ.ФизическоеЛицо КАК ФизическоеЛицо,
		СведенияОДоходахНДФЛ.Начисление КАК Начисление,
		СведенияОДоходахНДФЛ.ДокументОснование КАК ДокументНачисление,
		СведенияОДоходахНДФЛ.СуммаДохода КАК СуммаДоходаНДФЛ,
		СведенияОДоходахНДФЛ.СуммаВычета КАК СуммаВычетаНДФЛ,
		0 КАК СуммаВзносы,
		0 КАК СкидкаВзносы,
		СведенияОДоходахНДФЛ.КодДохода КАК КодДохода,
		ВЫБОР
			КОГДА СведенияОДоходахНДФЛ.СуммаВычета = 0
				ТОГДА ЗНАЧЕНИЕ(Справочник.ВидыВычетовНДФЛ.ПустаяСсылка)
			ИНАЧЕ СведенияОДоходахНДФЛ.КодВычета
		КОНЕЦ КАК КодВычета,
		ЗНАЧЕНИЕ(Справочник.ВидыДоходовПоСтраховымВзносам.ПустаяСсылка) КАК ВидДохода,
		СведенияОДоходахНДФЛ.ДатаПолученияДохода КАК ДатаПолученияДохода,
		СведенияОДоходахНДФЛ.Регистратор КАК Регистратор
	ИЗ
		РегистрНакопления.СведенияОДоходахНДФЛ КАК СведенияОДоходахНДФЛ
			ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВТОрганизацииАУСН КАК ОрганизацииАУСН
			ПО СведенияОДоходахНДФЛ.Организация = ОрганизацииАУСН.Организация
	ГДЕ
		СведенияОДоходахНДФЛ.МесяцНалоговогоПериода МЕЖДУ &НачалоПериода И &КонецПериода
		И СведенияОДоходахНДФЛ.Период МЕЖДУ ДОБАВИТЬКДАТЕ(&НачалоПериода, МЕСЯЦ, -18) И &КонецПериода
		И НЕ СведенияОДоходахНДФЛ.Регистратор ССЫЛКА Документ.ОперацияНалоговогоУчетаПоНДФЛ

	ОБЪЕДИНИТЬ ВСЕ

	ВЫБРАТЬ
		СведенияОДоходахСтраховыеВзносы.Организация,
		НАЧАЛОПЕРИОДА(СведенияОДоходахСтраховыеВзносы.ДатаПолученияДохода, МЕСЯЦ),
		СведенияОДоходахСтраховыеВзносы.ФизическоеЛицо,
		СведенияОДоходахСтраховыеВзносы.Начисление,
		СведенияОДоходахСтраховыеВзносы.Регистратор,
		0,
		0,
		СведенияОДоходахСтраховыеВзносы.Сумма,
		СведенияОДоходахСтраховыеВзносы.Скидка,
		ЗНАЧЕНИЕ(Справочник.ВидыДоходовНДФЛ.ПустаяСсылка),
		ЗНАЧЕНИЕ(Справочник.ВидыВычетовНДФЛ.ПустаяСсылка),
		СведенияОДоходахСтраховыеВзносы.ВидДохода,
		ДАТАВРЕМЯ(1, 1, 1, 0, 0, 0),
		СведенияОДоходахСтраховыеВзносы.Регистратор
	ИЗ
		РегистрНакопления.СведенияОДоходахСтраховыеВзносы КАК СведенияОДоходахСтраховыеВзносы
			ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВТОрганизацииАУСН КАК ОрганизацииАУСН
			ПО СведенияОДоходахСтраховыеВзносы.Организация = ОрганизацииАУСН.Организация
	ГДЕ
		СведенияОДоходахСтраховыеВзносы.ДатаПолученияДохода МЕЖДУ &НачалоПериода И &КонецПериода
		И СведенияОДоходахСтраховыеВзносы.Период МЕЖДУ ДОБАВИТЬКДАТЕ(&НачалоПериода, МЕСЯЦ, -18) И &КонецПериода
		И НЕ СведенияОДоходахСтраховыеВзносы.Регистратор ССЫЛКА Документ.ОперацияУчетаПоСтраховымВзносам) КАК ДанныеУчета

СГРУППИРОВАТЬ ПО
	ДанныеУчета.Организация,
	ДанныеУчета.Период,
	ДанныеУчета.ФизическоеЛицо,
	ДанныеУчета.Начисление,
	ДанныеУчета.ДокументНачисление,
	ДанныеУчета.КодДохода,
	ДанныеУчета.КодВычета,
	ДанныеУчета.ВидДохода,
	ДанныеУчета.ДатаПолученияДохода

ИМЕЮЩИЕ
	(СУММА(ДанныеУчета.СуммаДоходаНДФЛ) <> 0
		ИЛИ СУММА(ДанныеУчета.СуммаВычетаНДФЛ) <> 0
		ИЛИ СУММА(ДанныеУчета.СуммаВзносы) <> 0
		ИЛИ СУММА(ДанныеУчета.СкидкаВзносы) <> 0)

ИНДЕКСИРОВАТЬ ПО
	ДанныеУчета.ФизическоеЛицо,
	ДанныеУчета.Период,
	ДанныеУчета.Организация
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ РАЗЛИЧНЫЕ
	СведенияОДоходахНДФЛ.Организация КАК Организация,
	СведенияОДоходахНДФЛ.Период КАК Период,
	СведенияОДоходахНДФЛ.ФизическоеЛицо КАК ФизическоеЛицо
ПОМЕСТИТЬ ВТПериоды
ИЗ
	ВТДанныеУчета КАК СведенияОДоходахНДФЛ
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	Периоды.Период КАК Период,
	Периоды.Организация КАК Организация,
	Периоды.ФизическоеЛицо КАК ФизическоеЛицо
ПОМЕСТИТЬ ВТПериодыАУСН
ИЗ
	(ВЫБРАТЬ
		Периоды.Период КАК Период,
		Периоды.Организация КАК Организация,
		Периоды.ФизическоеЛицо КАК ФизическоеЛицо,
		МАКСИМУМ(ПрименяемыеТарифыСтраховыхВзносов.Период) КАК ПериодРегистра
	ИЗ
		ВТПериоды КАК Периоды
			ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.ПрименяемыеТарифыСтраховыхВзносов КАК ПрименяемыеТарифыСтраховыхВзносов
			ПО Периоды.Период >= ПрименяемыеТарифыСтраховыхВзносов.Период
				И Периоды.Организация = ПрименяемыеТарифыСтраховыхВзносов.ГоловнаяОрганизация

	СГРУППИРОВАТЬ ПО
		Периоды.Период,
		Периоды.Организация,
		Периоды.ФизическоеЛицо) КАК Периоды
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.ПрименяемыеТарифыСтраховыхВзносов КАК ПрименяемыеТарифыСтраховыхВзносов
		ПО Периоды.ПериодРегистра = ПрименяемыеТарифыСтраховыхВзносов.Период
			И Периоды.Организация = ПрименяемыеТарифыСтраховыхВзносов.ГоловнаяОрганизация
ГДЕ
	ПрименяемыеТарифыСтраховыхВзносов.ВидТарифа = ЗНАЧЕНИЕ(Справочник.ВидыТарифовСтраховыхВзносов.АУСН)
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	Периоды.Период КАК Период,
	Периоды.ФизическоеЛицо КАК ФизическоеЛицо,
	НЕ ЕСТЬNULL(СтатусыЗастрахованныхФизическихЛиц.ВидЗастрахованногоЛица, ЗНАЧЕНИЕ(Перечисление.ВидыЗастрахованныхЛицОбязательногоСтрахования.ГражданеРФ)) В (ЗНАЧЕНИЕ(Перечисление.ВидыЗастрахованныхЛицОбязательногоСтрахования.ВременноПребывающиеИностранцыПризнанныеБеженцами), ЗНАЧЕНИЕ(Перечисление.ВидыЗастрахованныхЛицОбязательногоСтрахования.ВременноПребывающиеИностранцыСтрахуемыеФСС), ЗНАЧЕНИЕ(Перечисление.ВидыЗастрахованныхЛицОбязательногоСтрахования.ВременноПребывающиеИностранцы), ЗНАЧЕНИЕ(Перечисление.ВидыЗастрахованныхЛицОбязательногоСтрахования.ВременноПребывающиеИностранцыНестрахуемые))
		ИЛИ ЕСТЬNULL(СтатусыЗастрахованныхФизическихЛиц.ВидЗастрахованногоЛица, ЗНАЧЕНИЕ(Перечисление.ВидыЗастрахованныхЛицОбязательногоСтрахования.ГражданеРФ)) В (ЗНАЧЕНИЕ(Перечисление.ВидыЗастрахованныхЛицОбязательногоСтрахования.ВременноПребывающиеИностранцы), ЗНАЧЕНИЕ(Перечисление.ВидыЗастрахованныхЛицОбязательногоСтрахования.ВременноПребывающиеИностранцыПризнанныеБеженцами), ЗНАЧЕНИЕ(Перечисление.ВидыЗастрахованныхЛицОбязательногоСтрахования.ВременноПребывающиеИностранцыСтрахуемыеФСС)) КАК ЗастрахованФСС,
	НЕ ЕСТЬNULL(СтатусыЗастрахованныхФизическихЛиц.ВидЗастрахованногоЛица, ЗНАЧЕНИЕ(Перечисление.ВидыЗастрахованныхЛицОбязательногоСтрахования.ГражданеРФ)) В (ЗНАЧЕНИЕ(Перечисление.ВидыЗастрахованныхЛицОбязательногоСтрахования.ВысококвалифицированныеСпециалистыВременноПроживающие), ЗНАЧЕНИЕ(Перечисление.ВидыЗастрахованныхЛицОбязательногоСтрахования.ВысококвалифицированныеСпециалистыПостоянноПроживающие), ЗНАЧЕНИЕ(Перечисление.ВидыЗастрахованныхЛицОбязательногоСтрахования.ВременноПребывающиеИностранцы), ЗНАЧЕНИЕ(Перечисление.ВидыЗастрахованныхЛицОбязательногоСтрахования.ВременноПребывающиеИностранцыСтрахуемыеФСС), ЗНАЧЕНИЕ(Перечисление.ВидыЗастрахованныхЛицОбязательногоСтрахования.ВременноПребывающиеИностранцыНестрахуемые)) КАК ЗастрахованФОМС,
	НЕ ЕСТЬNULL(СтатусыЗастрахованныхФизическихЛиц.ВидЗастрахованногоЛица, ЗНАЧЕНИЕ(Перечисление.ВидыЗастрахованныхЛицОбязательногоСтрахования.ГражданеРФ)) В (ЗНАЧЕНИЕ(Перечисление.ВидыЗастрахованныхЛицОбязательногоСтрахования.ВысококвалифицированныеСпециалистыИзЕАЭС), ЗНАЧЕНИЕ(Перечисление.ВидыЗастрахованныхЛицОбязательногоСтрахования.ВременноПребывающиеИностранцыСтрахуемыеФСС), ЗНАЧЕНИЕ(Перечисление.ВидыЗастрахованныхЛицОбязательногоСтрахования.ВременноПребывающиеИностранцыНестрахуемые)) КАК ЗастрахованПФР
ПОМЕСТИТЬ ВТСтатусыЗастрахованныхФизическихЛиц
ИЗ
	(ВЫБРАТЬ
		Периоды.Период КАК Период,
		Периоды.ФизическоеЛицо КАК ФизическоеЛицо,
		МАКСИМУМ(СтатусыЗастрахованныхФизическихЛиц.Период) КАК ПериодРегистра
	ИЗ
		ВТПериодыАУСН КАК Периоды
			ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.СтатусыЗастрахованныхФизическихЛиц КАК СтатусыЗастрахованныхФизическихЛиц
			ПО (КОНЕЦПЕРИОДА(Периоды.Период, МЕСЯЦ) >= СтатусыЗастрахованныхФизическихЛиц.Период)
				И (КОНЕЦПЕРИОДА(Периоды.Период, МЕСЯЦ) >= СтатусыЗастрахованныхФизическихЛиц.ДатаРегистрацииИзменений)
				И Периоды.ФизическоеЛицо = СтатусыЗастрахованныхФизическихЛиц.ФизическоеЛицо

	СГРУППИРОВАТЬ ПО
		Периоды.Период,
		Периоды.ФизическоеЛицо) КАК Периоды
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.СтатусыЗастрахованныхФизическихЛиц КАК СтатусыЗастрахованныхФизическихЛиц
		ПО Периоды.ПериодРегистра = СтатусыЗастрахованныхФизическихЛиц.Период
			И Периоды.ФизическоеЛицо = СтатусыЗастрахованныхФизическихЛиц.ФизическоеЛицо
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ РАЗЛИЧНЫЕ
	ПериодыАУСН.Период КАК Период,
	ПериодыАУСН.Организация КАК Организация,
	ПериодыАУСН.ФизическоеЛицо КАК ФизическоеЛицо,
	ДанныеУчета.Начисление КАК Начисление,
	ДанныеУчета.ДатаПолученияДохода КАК ДатаПолученияДохода
ПОМЕСТИТЬ ВТСтрокиОтчета
ИЗ
	ВТПериодыАУСН КАК ПериодыАУСН
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВТДанныеУчета КАК ДанныеУчета
		ПО ПериодыАУСН.Период = ДанныеУчета.Период
			И ПериодыАУСН.Организация = ДанныеУчета.Организация
			И ПериодыАУСН.ФизическоеЛицо = ДанныеУчета.ФизическоеЛицо
ГДЕ
	ДанныеУчета.ДатаПолученияДохода <> ДАТАВРЕМЯ(1, 1, 1, 0, 0, 0)

ИНДЕКСИРОВАТЬ ПО
	ФизическоеЛицо,
	Период,
	Организация
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	МИНИМУМ(ДанныеУчета.Начисление) КАК Начисление,
	НачисленияФизическихЛиц.ДатаПолученияДохода КАК ДатаПолученияДохода,
	НачисленияФизическихЛиц.Организация КАК Организация,
	НачисленияФизическихЛиц.Период КАК Период,
	НачисленияФизическихЛиц.ФизическоеЛицо КАК ФизическоеЛицо
ПОМЕСТИТЬ ВТПервыеСтрокиДатыПолученияДохода
ИЗ
	ВТСтрокиОтчета КАК НачисленияФизическихЛиц
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВТДанныеУчета КАК ДанныеУчета
		ПО НачисленияФизическихЛиц.Период = ДанныеУчета.Период
			И НачисленияФизическихЛиц.Организация = ДанныеУчета.Организация
			И НачисленияФизическихЛиц.ФизическоеЛицо = ДанныеУчета.ФизическоеЛицо
			И НачисленияФизическихЛиц.ДатаПолученияДохода = ДанныеУчета.ДатаПолученияДохода

СГРУППИРОВАТЬ ПО
	НачисленияФизическихЛиц.Организация,
	НачисленияФизическихЛиц.Период,
	НачисленияФизическихЛиц.ФизическоеЛицо,
	НачисленияФизическихЛиц.ДатаПолученияДохода
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	НачисленияФизическихЛиц.Начисление КАК Начисление,
	МАКСИМУМ(НачисленияФизическихЛиц.КодДохода) КАК КодДохода,
	МАКСИМУМ(НачисленияФизическихЛиц.ВидДохода) КАК ВидДохода
ПОМЕСТИТЬ ВТСоответствиеНачисленийИКодовДоходов
ИЗ
	ВТДанныеУчета КАК НачисленияФизическихЛиц

СГРУППИРОВАТЬ ПО
	НачисленияФизическихЛиц.Начисление
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	НачисленияФизическихЛиц.Период КАК Период,
	НачисленияФизическихЛиц.Организация КАК Организация,
	НачисленияФизическихЛиц.Начисление КАК Начисление,
	НачисленияФизическихЛиц.ФизическоеЛицо КАК ФизическоеЛицо,
	НачисленияФизическихЛиц.ДатаПолученияДохода КАК ДатаПолученияДохода,
	СУММА(ДанныеУчета.СуммаДоходаНДФЛ) КАК СуммаДохода,
	СУММА(ДанныеУчета.СуммаВычетаНДФЛ) КАК СуммаВычета,
	МАКСИМУМ(ДанныеУчета.КодДохода) КАК КодДохода,
	ДанныеУчета.КодВычета КАК КодВычета,
	ДанныеУчета.ДокументНачисление КАК ДокументНачисление
ПОМЕСТИТЬ ВТДанныеНДФЛ
ИЗ
	ВТСтрокиОтчета КАК НачисленияФизическихЛиц
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВТДанныеУчета КАК ДанныеУчета
		ПО НачисленияФизическихЛиц.Период = ДанныеУчета.Период
			И НачисленияФизическихЛиц.Организация = ДанныеУчета.Организация
			И НачисленияФизическихЛиц.ФизическоеЛицо = ДанныеУчета.ФизическоеЛицо
			И НачисленияФизическихЛиц.Начисление = ДанныеУчета.Начисление
			И НачисленияФизическихЛиц.ДатаПолученияДохода = ДанныеУчета.ДатаПолученияДохода
ГДЕ
	ДанныеУчета.КодДохода <> ЗНАЧЕНИЕ(Справочник.ВидыДоходовНДФЛ.ПустаяСсылка)

СГРУППИРОВАТЬ ПО
	НачисленияФизическихЛиц.Период,
	НачисленияФизическихЛиц.ФизическоеЛицо,
	НачисленияФизическихЛиц.Организация,
	НачисленияФизическихЛиц.Начисление,
	НачисленияФизическихЛиц.ДатаПолученияДохода,
	ДанныеУчета.КодВычета,
	ДанныеУчета.ДокументНачисление

ИМЕЮЩИЕ
	(СУММА(ДанныеУчета.СуммаДоходаНДФЛ) <> 0
		ИЛИ СУММА(ДанныеУчета.СуммаВычетаНДФЛ) <> 0)
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ДанныеУчета.Период КАК Период,
	ДанныеУчета.Организация КАК Организация,
	ДанныеУчета.ФизическоеЛицо КАК ФизическоеЛицо,
	ДанныеУчета.Начисление КАК Начисление,
	СУММА(ДанныеУчета.СуммаВзносы) КАК СуммаДохода,
	СУММА(ДанныеУчета.СкидкаВзносы) КАК СуммаВычета,
	МАКСИМУМ(ДанныеУчета.ВидДохода) КАК ВидДохода
ПОМЕСТИТЬ ВТДанныеВзносы
ИЗ
	ВТПериодыАУСН КАК ПериодыАУСН
		ЛЕВОЕ СОЕДИНЕНИЕ ВТДанныеУчета КАК ДанныеУчета
			ЛЕВОЕ СОЕДИНЕНИЕ ВТДанныеНДФЛ КАК ДанныеНДФЛ
			ПО ДанныеУчета.Начисление = ДанныеНДФЛ.Начисление
				И ДанныеУчета.Организация = ДанныеНДФЛ.Организация
				И ДанныеУчета.ДокументНачисление = ДанныеНДФЛ.ДокументНачисление
				И ДанныеУчета.ФизическоеЛицо = ДанныеНДФЛ.ФизическоеЛицо
		ПО ПериодыАУСН.Период = ДанныеУчета.Период
			И ПериодыАУСН.Организация = ДанныеУчета.Организация
			И ПериодыАУСН.ФизическоеЛицо = ДанныеУчета.ФизическоеЛицо
ГДЕ
	ДанныеНДФЛ.ФизическоеЛицо ЕСТЬ NULL
	И ДанныеУчета.ДатаПолученияДохода = ДАТАВРЕМЯ(1, 1, 1, 0, 0, 0)

СГРУППИРОВАТЬ ПО
	ДанныеУчета.Период,
	ДанныеУчета.ФизическоеЛицо,
	ДанныеУчета.Организация,
	ДанныеУчета.Начисление

ИМЕЮЩИЕ
	(СУММА(ДанныеУчета.СуммаВзносы) <> 0
		ИЛИ СУММА(ДанныеУчета.СкидкаВзносы) <> 0)
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	МИНИМУМ(СтрокиОтчета.ДатаПолученияДохода) КАК ДатаПолученияДохода,
	МИНИМУМ(СтрокиОтчета.Начисление) КАК Начисление,
	СтрокиОтчета.Организация КАК Организация,
	СтрокиОтчета.Период КАК Период,
	СтрокиОтчета.ФизическоеЛицо КАК ФизическоеЛицо
ПОМЕСТИТЬ ВТПервыеСтрокиПериода
ИЗ
	ВТСтрокиОтчета КАК СтрокиОтчета

СГРУППИРОВАТЬ ПО
	СтрокиОтчета.Организация,
	СтрокиОтчета.Период,
	СтрокиОтчета.ФизическоеЛицо
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ РАЗРЕШЕННЫЕ
	ПериодыАУСН.Организация КАК Организация,
	ПериодыАУСН.Период КАК Период,
	ПериодыАУСН.ФизическоеЛицо КАК ФизическоеЛицо,
	ПериодыАУСН.Начисление КАК Начисление,
	ПериодыАУСН.ДатаПолученияДохода КАК ДатаПолученияДохода,
	ПредоставленныеСтандартныеИСоциальныеВычетыНДФЛ.КодВычета КАК КодВычета,
	СУММА(ПредоставленныеСтандартныеИСоциальныеВычетыНДФЛ.Сумма) КАК Сумма
ПОМЕСТИТЬ ВТПредоставленныеВычеты
ИЗ
	ВТПервыеСтрокиПериода КАК ПериодыАУСН
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрНакопления.ПредоставленныеСтандартныеИСоциальныеВычетыНДФЛ КАК ПредоставленныеСтандартныеИСоциальныеВычетыНДФЛ
		ПО (ПериодыАУСН.Период = НАЧАЛОПЕРИОДА(ПредоставленныеСтандартныеИСоциальныеВычетыНДФЛ.МесяцНалоговогоПериода, МЕСЯЦ))
			И ПериодыАУСН.Организация = ПредоставленныеСтандартныеИСоциальныеВычетыНДФЛ.Организация
			И ПериодыАУСН.ФизическоеЛицо = ПредоставленныеСтандартныеИСоциальныеВычетыНДФЛ.ФизическоеЛицо

СГРУППИРОВАТЬ ПО
	ПериодыАУСН.Организация,
	ПериодыАУСН.Период,
	ПериодыАУСН.ФизическоеЛицо,
	ПредоставленныеСтандартныеИСоциальныеВычетыНДФЛ.КодВычета,
	ПериодыАУСН.ДатаПолученияДохода,
	ПериодыАУСН.Начисление

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
	ПериодыАУСН.Организация,
	ПериодыАУСН.Период,
	ПериодыАУСН.ФизическоеЛицо,
	ПериодыАУСН.Начисление,
	ПериодыАУСН.ДатаПолученияДохода,
	ИмущественныеВычетыНДФЛ.КодВычета,
	СУММА(ИмущественныеВычетыНДФЛ.Сумма)
ИЗ
	ВТПервыеСтрокиПериода КАК ПериодыАУСН
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрНакопления.ИмущественныеВычетыНДФЛ КАК ИмущественныеВычетыНДФЛ
		ПО (ПериодыАУСН.Период = НАЧАЛОПЕРИОДА(ИмущественныеВычетыНДФЛ.Период, МЕСЯЦ))
			И ПериодыАУСН.Организация = ИмущественныеВычетыНДФЛ.Организация
			И ПериодыАУСН.ФизическоеЛицо = ИмущественныеВычетыНДФЛ.ФизическоеЛицо
ГДЕ
	ИмущественныеВычетыНДФЛ.ВидДвижения = ЗНАЧЕНИЕ(ВидДвиженияНакопления.Расход)

СГРУППИРОВАТЬ ПО
	ПериодыАУСН.Организация,
	ПериодыАУСН.Период,
	ПериодыАУСН.ФизическоеЛицо,
	ИмущественныеВычетыНДФЛ.КодВычета,
	ПериодыАУСН.ДатаПолученияДохода,
	ПериодыАУСН.Начисление
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ПредоставленныеВычеты.Организация КАК Организация,
	ПредоставленныеВычеты.Период КАК Период,
	ПредоставленныеВычеты.ФизическоеЛицо КАК ФизическоеЛицо,
	ПредоставленныеВычеты.Начисление КАК Начисление,
	ПредоставленныеВычеты.ДатаПолученияДохода КАК ДатаПолученияДохода,
	МИНИМУМ(ПредоставленныеВычеты.КодВычета) КАК КодВычета
ПОМЕСТИТЬ ВТКодыПервыхВычетов
ИЗ
	ВТПредоставленныеВычеты КАК ПредоставленныеВычеты
		ЛЕВОЕ СОЕДИНЕНИЕ ВТДанныеНДФЛ КАК ДанныеНДФЛ
		ПО ПредоставленныеВычеты.Организация = ДанныеНДФЛ.Организация
			И ПредоставленныеВычеты.Период = ДанныеНДФЛ.Период
			И ПредоставленныеВычеты.ФизическоеЛицо = ДанныеНДФЛ.ФизическоеЛицо
			И ПредоставленныеВычеты.ДатаПолученияДохода = ДанныеНДФЛ.ДатаПолученияДохода
			И ПредоставленныеВычеты.Начисление = ДанныеНДФЛ.Начисление
ГДЕ
	ДанныеНДФЛ.КодВычета = ЗНАЧЕНИЕ(Справочник.ВидыВычетовНДФЛ.ПустаяСсылка)

СГРУППИРОВАТЬ ПО
	ПредоставленныеВычеты.Организация,
	ПредоставленныеВычеты.Период,
	ПредоставленныеВычеты.ФизическоеЛицо,
	ПредоставленныеВычеты.Начисление,
	ПредоставленныеВычеты.ДатаПолученияДохода
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ РАЗРЕШЕННЫЕ
	ПериодыАУСН.ФизическоеЛицо КАК ФизическоеЛицо,
	ПериодыАУСН.Период КАК Период,
	ПериодыАУСН.Организация КАК Организация,
	ПериодыАУСН.Начисление КАК Начисление,
	ПериодыАУСН.ДатаПолученияДохода КАК ДатаПолученияДохода,
	СУММА(ВЫБОР
			КОГДА РасчетыНалогоплательщиковСБюджетомПоНДФЛ.ВидДвижения = ЗНАЧЕНИЕ(ВидДвиженияНакопления.Приход)
				ТОГДА РасчетыНалогоплательщиковСБюджетомПоНДФЛ.Сумма + РасчетыНалогоплательщиковСБюджетомПоНДФЛ.СуммаСПревышения
			ИНАЧЕ 0
		КОНЕЦ) КАК Начислено,
	СУММА(ВЫБОР
			КОГДА РасчетыНалогоплательщиковСБюджетомПоНДФЛ.ВариантУдержания = ЗНАЧЕНИЕ(Перечисление.ВариантыУдержанияНДФЛ.Удержано)
				ТОГДА РасчетыНалогоплательщиковСБюджетомПоНДФЛ.Сумма + РасчетыНалогоплательщиковСБюджетомПоНДФЛ.СуммаСПревышения
			КОГДА РасчетыНалогоплательщиковСБюджетомПоНДФЛ.ВариантУдержания = ЗНАЧЕНИЕ(Перечисление.ВариантыУдержанияНДФЛ.ВозвращеноНалоговымАгентом)
				ТОГДА РасчетыНалогоплательщиковСБюджетомПоНДФЛ.Сумма + РасчетыНалогоплательщиковСБюджетомПоНДФЛ.СуммаСПревышения
			ИНАЧЕ 0
		КОНЕЦ) КАК Удержано
ПОМЕСТИТЬ ВТНалоги
ИЗ
	ВТПервыеСтрокиДатыПолученияДохода КАК ПериодыАУСН
		ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.РасчетыНалогоплательщиковСБюджетомПоНДФЛ КАК РасчетыНалогоплательщиковСБюджетомПоНДФЛ
		ПО ПериодыАУСН.Организация = РасчетыНалогоплательщиковСБюджетомПоНДФЛ.Организация
			И ПериодыАУСН.ФизическоеЛицо = РасчетыНалогоплательщиковСБюджетомПоНДФЛ.ФизическоеЛицо
			И (ПериодыАУСН.Период = НАЧАЛОПЕРИОДА(РасчетыНалогоплательщиковСБюджетомПоНДФЛ.МесяцНалоговогоПериода, МЕСЯЦ))
			И ПериодыАУСН.ДатаПолученияДохода = РасчетыНалогоплательщиковСБюджетомПоНДФЛ.МесяцНалоговогоПериода
ГДЕ
	РасчетыНалогоплательщиковСБюджетомПоНДФЛ.Период МЕЖДУ ДОБАВИТЬКДАТЕ(&НачалоПериода, МЕСЯЦ, -18) И &КонецПериода

СГРУППИРОВАТЬ ПО
	ПериодыАУСН.ФизическоеЛицо,
	ПериодыАУСН.Период,
	ПериодыАУСН.ДатаПолученияДохода,
	ПериодыАУСН.Организация,
	ПериодыАУСН.Начисление
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	СтрокиОтчета.ОписаниеСтроки КАК ОписаниеСтроки,
	СтрокиОтчета.Период КАК Период,
	СтрокиОтчета.Организация КАК Организация,
	СтрокиОтчета.Начисление КАК Начисление,
	СтрокиОтчета.ФизическоеЛицо КАК ФизическоеЛицо,
	СтрокиОтчета.ДатаПолученияДохода КАК ДатаПолученияДохода,
	СтрокиОтчета.КодДохода КАК КодДохода,
	СУММА(СтрокиОтчета.СуммаДохода) КАК СуммаДохода,
	СтрокиОтчета.КодВычета КАК КодВычета,
	СУММА(СтрокиОтчета.СуммаВычета) КАК СуммаВычета,
	СтрокиОтчета.ВидДохода КАК ВидДохода,
	СУММА(СтрокиОтчета.Начислено) КАК Начислено,
	СУММА(СтрокиОтчета.Удержано) КАК Удержано
ПОМЕСТИТЬ ВТВсеСтрокиОтчета
ИЗ
	(ВЫБРАТЬ
		1 КАК ОписаниеСтроки,
		ДанныеНДФЛ.Период КАК Период,
		ДанныеНДФЛ.Организация КАК Организация,
		ДанныеНДФЛ.Начисление КАК Начисление,
		ДанныеНДФЛ.ФизическоеЛицо КАК ФизическоеЛицо,
		ДанныеНДФЛ.ДатаПолученияДохода КАК ДатаПолученияДохода,
		ДанныеНДФЛ.КодДохода КАК КодДохода,
		СУММА(ДанныеНДФЛ.СуммаДохода) КАК СуммаДохода,
		ВЫБОР
			КОГДА ДанныеНДФЛ.КодВычета = ЗНАЧЕНИЕ(Справочник.ВидыВычетовНДФЛ.ПустаяСсылка)
				ТОГДА ЕСТЬNULL(ПредоставленныеВычеты.КодВычета, ЗНАЧЕНИЕ(Справочник.ВидыВычетовНДФЛ.ПустаяСсылка))
			ИНАЧЕ ДанныеНДФЛ.КодВычета
		КОНЕЦ КАК КодВычета,
		СУММА(ВЫБОР
				КОГДА ДанныеНДФЛ.КодВычета = ЗНАЧЕНИЕ(Справочник.ВидыВычетовНДФЛ.ПустаяСсылка)
					ТОГДА ЕСТЬNULL(ПредоставленныеВычеты.Сумма, 0)
				ИНАЧЕ ДанныеНДФЛ.СуммаВычета
			КОНЕЦ) КАК СуммаВычета,
		ЕСТЬNULL(СоответствиеНачисленийИКодовДоходов.ВидДохода, ЗНАЧЕНИЕ(Справочник.ВидыДоходовПоСтраховымВзносам.ПустаяСсылка)) КАК ВидДохода,
		МАКСИМУМ(ЕСТЬNULL(Налоги.Начислено, 0)) КАК Начислено,
		МАКСИМУМ(ЕСТЬNULL(Налоги.Удержано, 0)) КАК Удержано
	ИЗ
		ВТДанныеНДФЛ КАК ДанныеНДФЛ
			ЛЕВОЕ СОЕДИНЕНИЕ ВТНалоги КАК Налоги
			ПО ДанныеНДФЛ.Период = Налоги.Период
				И ДанныеНДФЛ.Организация = Налоги.Организация
				И ДанныеНДФЛ.ДатаПолученияДохода = Налоги.ДатаПолученияДохода
				И ДанныеНДФЛ.ФизическоеЛицо = Налоги.ФизическоеЛицо
				И ДанныеНДФЛ.Начисление = Налоги.Начисление
			ЛЕВОЕ СОЕДИНЕНИЕ ВТСоответствиеНачисленийИКодовДоходов КАК СоответствиеНачисленийИКодовДоходов
			ПО ДанныеНДФЛ.Начисление = СоответствиеНачисленийИКодовДоходов.Начисление
			ЛЕВОЕ СОЕДИНЕНИЕ ВТКодыПервыхВычетов КАК КодыПервыхВычетов
				ЛЕВОЕ СОЕДИНЕНИЕ ВТПредоставленныеВычеты КАК ПредоставленныеВычеты
				ПО КодыПервыхВычетов.Организация = ПредоставленныеВычеты.Организация
					И КодыПервыхВычетов.Период = ПредоставленныеВычеты.Период
					И КодыПервыхВычетов.ФизическоеЛицо = ПредоставленныеВычеты.ФизическоеЛицо
					И КодыПервыхВычетов.Начисление = ПредоставленныеВычеты.Начисление
					И КодыПервыхВычетов.ДатаПолученияДохода = ПредоставленныеВычеты.ДатаПолученияДохода
					И КодыПервыхВычетов.КодВычета = ПредоставленныеВычеты.КодВычета
			ПО ДанныеНДФЛ.Начисление = КодыПервыхВычетов.Начисление
				И ДанныеНДФЛ.Организация = КодыПервыхВычетов.Организация
				И ДанныеНДФЛ.Период = КодыПервыхВычетов.Период
				И ДанныеНДФЛ.ФизическоеЛицо = КодыПервыхВычетов.ФизическоеЛицо
				И ДанныеНДФЛ.ДатаПолученияДохода = КодыПервыхВычетов.ДатаПолученияДохода

	СГРУППИРОВАТЬ ПО
		ДанныеНДФЛ.Период,
		ДанныеНДФЛ.Организация,
		ДанныеНДФЛ.Начисление,
		ДанныеНДФЛ.ФизическоеЛицо,
		ДанныеНДФЛ.ДатаПолученияДохода,
		ДанныеНДФЛ.КодДохода,
		ЕСТЬNULL(СоответствиеНачисленийИКодовДоходов.ВидДохода, ЗНАЧЕНИЕ(Справочник.ВидыДоходовПоСтраховымВзносам.ПустаяСсылка)),
		ВЫБОР
			КОГДА ДанныеНДФЛ.КодВычета = ЗНАЧЕНИЕ(Справочник.ВидыВычетовНДФЛ.ПустаяСсылка)
				ТОГДА ЕСТЬNULL(ПредоставленныеВычеты.КодВычета, ЗНАЧЕНИЕ(Справочник.ВидыВычетовНДФЛ.ПустаяСсылка))
			ИНАЧЕ ДанныеНДФЛ.КодВычета
		КОНЕЦ

	ОБЪЕДИНИТЬ ВСЕ

	ВЫБРАТЬ
		2,
		ДанныеВзносы.Период,
		ДанныеВзносы.Организация,
		ДанныеВзносы.Начисление,
		ДанныеВзносы.ФизическоеЛицо,
		ДанныеВзносы.Период,
		ЗНАЧЕНИЕ(Справочник.ВидыДоходовНДФЛ.ПустаяСсылка),
		ДанныеВзносы.СуммаДохода,
		ЗНАЧЕНИЕ(Справочник.ВидыВычетовНДФЛ.ПустаяСсылка),
		ДанныеВзносы.СуммаВычета,
		ДанныеВзносы.ВидДохода,
		0,
		0
	ИЗ
		ВТДанныеВзносы КАК ДанныеВзносы

	ОБЪЕДИНИТЬ ВСЕ

	ВЫБРАТЬ
		3,
		ПредоставленныеВычеты.Период,
		ПредоставленныеВычеты.Организация,
		ПредоставленныеВычеты.Начисление,
		ПредоставленныеВычеты.ФизическоеЛицо,
		ПредоставленныеВычеты.ДатаПолученияДохода,
		ЕСТЬNULL(СоответствиеНачисленийИКодовДоходов.КодДохода, ЗНАЧЕНИЕ(Справочник.ВидыДоходовНДФЛ.ПустаяСсылка)),
		0,
		ПредоставленныеВычеты.КодВычета,
		ПредоставленныеВычеты.Сумма,
		ЗНАЧЕНИЕ(Справочник.ВидыДоходовПоСтраховымВзносам.ПустаяСсылка),
		0,
		0
	ИЗ
		ВТПредоставленныеВычеты КАК ПредоставленныеВычеты
			ЛЕВОЕ СОЕДИНЕНИЕ ВТСоответствиеНачисленийИКодовДоходов КАК СоответствиеНачисленийИКодовДоходов
			ПО ПредоставленныеВычеты.Начисление = СоответствиеНачисленийИКодовДоходов.Начисление
			ЛЕВОЕ СОЕДИНЕНИЕ ВТКодыПервыхВычетов КАК КодыПервыхВычетов
			ПО ПредоставленныеВычеты.Начисление = КодыПервыхВычетов.Начисление
				И ПредоставленныеВычеты.Организация = КодыПервыхВычетов.Организация
				И ПредоставленныеВычеты.Период = КодыПервыхВычетов.Период
				И ПредоставленныеВычеты.ФизическоеЛицо = КодыПервыхВычетов.ФизическоеЛицо
				И ПредоставленныеВычеты.ДатаПолученияДохода = КодыПервыхВычетов.ДатаПолученияДохода
				И ПредоставленныеВычеты.КодВычета = КодыПервыхВычетов.КодВычета
	ГДЕ
		КодыПервыхВычетов.КодВычета ЕСТЬ NULL) КАК СтрокиОтчета

СГРУППИРОВАТЬ ПО
	СтрокиОтчета.ОписаниеСтроки,
	СтрокиОтчета.КодДохода,
	СтрокиОтчета.Период,
	СтрокиОтчета.ФизическоеЛицо,
	СтрокиОтчета.Начисление,
	СтрокиОтчета.ВидДохода,
	СтрокиОтчета.Организация,
	СтрокиОтчета.КодВычета,
	СтрокиОтчета.ДатаПолученияДохода
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ВсеСтрокиОтчета.Организация КАК Организация,
	ВсеСтрокиОтчета.Период КАК Период,
	ВсеСтрокиОтчета.ФизическоеЛицо КАК ФизическоеЛицо,
	ВсеСтрокиОтчета.ДатаПолученияДохода КАК ДатаПолученияДохода,
	ВсеСтрокиОтчета.Начисление КАК Начисление,
	ВЫБОР
		КОГДА ВсеСтрокиОтчета.ОписаниеСтроки = 1
				И ВсеСтрокиОтчета.КодДохода.НеОблагаетсяУНалоговогоАгента
			ТОГДА "4903"
		КОГДА ВсеСтрокиОтчета.ОписаниеСтроки = 1
				И ВсеСтрокиОтчета.КодДохода.КодПрименяемыйВНалоговойОтчетностиС2021Года В ("2610", "2630", "2640", "2641")
				И (ВсеСтрокиОтчета.ДатаПолученияДохода МЕЖДУ ДАТАВРЕМЯ(2021, 1, 1, 0, 0, 0) И ДАТАВРЕМЯ(2023, 12, 31, 23, 59, 59))
			ТОГДА "4901"
		КОГДА ВсеСтрокиОтчета.ОписаниеСтроки = 1
				ИЛИ ВсеСтрокиОтчета.ОписаниеСтроки = 3
			ТОГДА ЕСТЬNULL(ВсеСтрокиОтчета.КодДохода.КодПрименяемыйВНалоговойОтчетностиС2021Года, "")
		КОГДА ВсеСтрокиОтчета.ОписаниеСтроки = 2
				И ВсеСтрокиОтчета.ВидДохода = ЗНАЧЕНИЕ(Справочник.ВидыДоходовПоСтраховымВзносам.НеЯвляетсяОбъектом)
			ТОГДА "4902"
		КОГДА ВсеСтрокиОтчета.ОписаниеСтроки = 2
				И НЕ ВсеСтрокиОтчета.ВидДохода.ВходитВБазуФОМС
			ТОГДА "4901"
		ИНАЧЕ ""
	КОНЕЦ КАК КодВыплачиваемогоДохода,
	СУММА(ВсеСтрокиОтчета.СуммаДохода) КАК СуммаДохода,
	ЕСТЬNULL(ВсеСтрокиОтчета.КодВычета.КодПрименяемыйВНалоговойОтчетностиС2010Года, "") КАК КодВычета,
	СУММА(ВсеСтрокиОтчета.СуммаВычета) КАК СуммаВычета,
	ВЫБОР
		КОГДА ВсеСтрокиОтчета.ВидДохода = "01"
			ТОГДА "01"
		КОГДА ВсеСтрокиОтчета.ВидДохода = "02"
			ТОГДА "02"
		КОГДА ВсеСтрокиОтчета.ВидДохода = "03"
			ТОГДА "03"
		КОГДА НЕ СтатусыЗастрахованныхФизическихЛиц.ЗастрахованФСС
				И НЕ СтатусыЗастрахованныхФизическихЛиц.ЗастрахованПФР
				И НЕ СтатусыЗастрахованныхФизическихЛиц.ЗастрахованФОМС
			ТОГДА "01"
		КОГДА НЕ СтатусыЗастрахованныхФизическихЛиц.ЗастрахованФОМС
			ТОГДА "04"
		КОГДА ВсеСтрокиОтчета.ВидДохода = ЗНАЧЕНИЕ(Справочник.ВидыДоходовПоСтраховымВзносам.НеЯвляетсяОбъектом)
			ТОГДА "01"
		КОГДА НЕ ВсеСтрокиОтчета.ВидДохода.ВходитВБазуФОМС
			ТОГДА "01"
		КОГДА НЕ ВсеСтрокиОтчета.ВидДохода.ВходитВБазуФСС
			ТОГДА "03"
		КОГДА НЕ ВсеСтрокиОтчета.ВидДохода.ВходитВБазуПФР
			ТОГДА "02"
		ИНАЧЕ ""
	КОНЕЦ КАК КодНеоблагаемогоВзносамиДохода,
	СУММА(ВЫБОР
			КОГДА ВЫБОР
					КОГДА ВсеСтрокиОтчета.ВидДохода = "01"
						ТОГДА "01"
					КОГДА ВсеСтрокиОтчета.ВидДохода = "02"
						ТОГДА "02"
					КОГДА ВсеСтрокиОтчета.ВидДохода = "03"
						ТОГДА "03"
					КОГДА НЕ СтатусыЗастрахованныхФизическихЛиц.ЗастрахованФСС
							И НЕ СтатусыЗастрахованныхФизическихЛиц.ЗастрахованПФР
							И НЕ СтатусыЗастрахованныхФизическихЛиц.ЗастрахованФОМС
						ТОГДА "01"
					КОГДА НЕ СтатусыЗастрахованныхФизическихЛиц.ЗастрахованФОМС
						ТОГДА "04"
					КОГДА ВсеСтрокиОтчета.ВидДохода = ЗНАЧЕНИЕ(Справочник.ВидыДоходовПоСтраховымВзносам.НеЯвляетсяОбъектом)
						ТОГДА "01"
					КОГДА НЕ ВсеСтрокиОтчета.ВидДохода.ВходитВБазуФОМС
						ТОГДА "01"
					КОГДА НЕ ВсеСтрокиОтчета.ВидДохода.ВходитВБазуФСС
						ТОГДА "03"
					КОГДА НЕ ВсеСтрокиОтчета.ВидДохода.ВходитВБазуПФР
						ТОГДА "02"
					ИНАЧЕ ""
				КОНЕЦ = ""
				ТОГДА 0
			ИНАЧЕ ВсеСтрокиОтчета.СуммаДохода
		КОНЕЦ) КАК СуммаНеоблагаемогоВзносамиДохода,
	СУММА(ВсеСтрокиОтчета.Начислено) КАК НачисленоНДФЛ,
	СУММА(ВсеСтрокиОтчета.Удержано) КАК УдержаноНДФЛ
ПОМЕСТИТЬ ВТОбработанныеСтроки
ИЗ
	ВТВсеСтрокиОтчета КАК ВсеСтрокиОтчета
		ЛЕВОЕ СОЕДИНЕНИЕ ВТСтатусыЗастрахованныхФизическихЛиц КАК СтатусыЗастрахованныхФизическихЛиц
		ПО ВсеСтрокиОтчета.Период = СтатусыЗастрахованныхФизическихЛиц.Период
			И ВсеСтрокиОтчета.ФизическоеЛицо = СтатусыЗастрахованныхФизическихЛиц.ФизическоеЛицо

СГРУППИРОВАТЬ ПО
	ВсеСтрокиОтчета.Организация,
	ВсеСтрокиОтчета.Период,
	ВсеСтрокиОтчета.ФизическоеЛицо,
	ВсеСтрокиОтчета.ДатаПолученияДохода,
	ВсеСтрокиОтчета.Начисление,
	ЕСТЬNULL(ВсеСтрокиОтчета.КодВычета.КодПрименяемыйВНалоговойОтчетностиС2010Года, ""),
	ВЫБОР
		КОГДА ВсеСтрокиОтчета.ОписаниеСтроки = 1
				И ВсеСтрокиОтчета.КодДохода.НеОблагаетсяУНалоговогоАгента
			ТОГДА "4903"
		КОГДА ВсеСтрокиОтчета.ОписаниеСтроки = 1
				И ВсеСтрокиОтчета.КодДохода.КодПрименяемыйВНалоговойОтчетностиС2021Года В ("2610", "2630", "2640", "2641")
				И (ВсеСтрокиОтчета.ДатаПолученияДохода МЕЖДУ ДАТАВРЕМЯ(2021, 1, 1, 0, 0, 0) И ДАТАВРЕМЯ(2023, 12, 31, 23, 59, 59))
			ТОГДА "4901"
		КОГДА ВсеСтрокиОтчета.ОписаниеСтроки = 1
				ИЛИ ВсеСтрокиОтчета.ОписаниеСтроки = 3
			ТОГДА ЕСТЬNULL(ВсеСтрокиОтчета.КодДохода.КодПрименяемыйВНалоговойОтчетностиС2021Года, "")
		КОГДА ВсеСтрокиОтчета.ОписаниеСтроки = 2
				И ВсеСтрокиОтчета.ВидДохода = ЗНАЧЕНИЕ(Справочник.ВидыДоходовПоСтраховымВзносам.НеЯвляетсяОбъектом)
			ТОГДА "4902"
		КОГДА ВсеСтрокиОтчета.ОписаниеСтроки = 2
				И НЕ ВсеСтрокиОтчета.ВидДохода.ВходитВБазуФОМС
			ТОГДА "4901"
		ИНАЧЕ ""
	КОНЕЦ,
	ВЫБОР
		КОГДА ВсеСтрокиОтчета.ВидДохода = "01"
			ТОГДА "01"
		КОГДА ВсеСтрокиОтчета.ВидДохода = "02"
			ТОГДА "02"
		КОГДА ВсеСтрокиОтчета.ВидДохода = "03"
			ТОГДА "03"
		КОГДА НЕ СтатусыЗастрахованныхФизическихЛиц.ЗастрахованФСС
				И НЕ СтатусыЗастрахованныхФизическихЛиц.ЗастрахованПФР
				И НЕ СтатусыЗастрахованныхФизическихЛиц.ЗастрахованФОМС
			ТОГДА "01"
		КОГДА НЕ СтатусыЗастрахованныхФизическихЛиц.ЗастрахованФОМС
			ТОГДА "04"
		КОГДА ВсеСтрокиОтчета.ВидДохода = ЗНАЧЕНИЕ(Справочник.ВидыДоходовПоСтраховымВзносам.НеЯвляетсяОбъектом)
			ТОГДА "01"
		КОГДА НЕ ВсеСтрокиОтчета.ВидДохода.ВходитВБазуФОМС
			ТОГДА "01"
		КОГДА НЕ ВсеСтрокиОтчета.ВидДохода.ВходитВБазуФСС
			ТОГДА "03"
		КОГДА НЕ ВсеСтрокиОтчета.ВидДохода.ВходитВБазуПФР
			ТОГДА "02"
		ИНАЧЕ ""
	КОНЕЦ
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ОбработанныеСтроки.Организация КАК Организация,
	ОбработанныеСтроки.Период КАК Период,
	ОбработанныеСтроки.ФизическоеЛицо КАК ФизическоеЛицо,
	ОбработанныеСтроки.ДатаПолученияДохода КАК ДатаПолученияДохода,
	ОбработанныеСтроки.Начисление КАК Начисление,
	ОбработанныеСтроки.КодВыплачиваемогоДохода КАК КодВыплачиваемогоДохода,
	ОбработанныеСтроки.СуммаДохода КАК СуммаДохода,
	ОбработанныеСтроки.КодВычета КАК КодВычета,
	ОбработанныеСтроки.СуммаВычета КАК СуммаВычета,
	ОбработанныеСтроки.КодНеоблагаемогоВзносамиДохода КАК КодНеоблагаемогоВзносамиДохода,
	ОбработанныеСтроки.СуммаНеоблагаемогоВзносамиДохода КАК СуммаНеоблагаемогоВзносамиДохода,
	ОбработанныеСтроки.НачисленоНДФЛ КАК НачисленоНДФЛ,
	ОбработанныеСтроки.УдержаноНДФЛ КАК УдержаноНДФЛ
{ВЫБРАТЬ
	Организация.*,
	ФизическоеЛицо.*,
	Период,
	ДатаПолученияДохода,
	Начисление.*,
	КодВыплачиваемогоДохода,
	СуммаДохода,
	КодВычета,
	СуммаВычета,
	КодНеоблагаемогоВзносамиДохода,
	СуммаНеоблагаемогоВзносамиДохода,
	НачисленоНДФЛ,
	УдержаноНДФЛ}
ИЗ
	ВТОбработанныеСтроки КАК ОбработанныеСтроки
ГДЕ
	(ОбработанныеСтроки.КодВыплачиваемогоДохода <> ""
			ИЛИ ОбработанныеСтроки.КодВычета <> ""
			ИЛИ ОбработанныеСтроки.КодНеоблагаемогоВзносамиДохода <> "")
	И (ОбработанныеСтроки.СуммаДохода <> 0
			ИЛИ ОбработанныеСтроки.СуммаВычета <> 0
			ИЛИ ОбработанныеСтроки.СуммаНеоблагаемогоВзносамиДохода <> 0
			ИЛИ ОбработанныеСтроки.НачисленоНДФЛ <> 0
			ИЛИ ОбработанныеСтроки.УдержаноНДФЛ <> 0)
{ГДЕ
	ОбработанныеСтроки.Организация.*,
	ОбработанныеСтроки.ФизическоеЛицо.*,
	ОбработанныеСтроки.Начисление.*}