"Заявление ДСВ-1" для 1С:ЗУП

ВЫБРАТЬ РАЗРЕШЕННЫЕ
	Сотрудники.ФизическоеЛицо.СтраховойНомерПФР КАК СтраховойНомерПФР,
	Сотрудники.ФизическоеЛицо КАК ФизическоеЛицо,
	ТекущиеКадровыеДанныеСотрудников.ТекущаяОрганизация КАК Организация,
	ТекущиеКадровыеДанныеСотрудников.ТекущаяОрганизация.НаименованиеТерриториальногоОрганаПФР КАК НаименованиеПФР
ПОМЕСТИТЬ ВТСотрудники
ИЗ
	Справочник.Сотрудники КАК Сотрудники
		ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ТекущиеКадровыеДанныеСотрудников КАК ТекущиеКадровыеДанныеСотрудников
		ПО Сотрудники.Ссылка = ТекущиеКадровыеДанныеСотрудников.Сотрудник
			И Сотрудники.ФизическоеЛицо = ТекущиеКадровыеДанныеСотрудников.ФизическоеЛицо
		ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ВидыЗанятостиСотрудниковИнтервальный КАК ВидыЗанятостиСотрудников
		ПО Сотрудники.Ссылка = ВидыЗанятостиСотрудников.Сотрудник
			И (ДАТАВРЕМЯ(3999, 12, 31, 23, 59, 59) МЕЖДУ ВидыЗанятостиСотрудников.ДатаНачала И ВидыЗанятостиСотрудников.ДатаОкончания)
ГДЕ
	ТекущиеКадровыеДанныеСотрудников.ДатаПриема <= &Период
	И ВидыЗанятостиСотрудников.ВидЗанятости <> ЗНАЧЕНИЕ(Перечисление.ВидыЗанятости.ВнутреннееСовместительство)
{ГДЕ
	Сотрудники.ФизическоеЛицо.* КАК ФизическоеЛицо,
	ТекущиеКадровыеДанныеСотрудников.ТекущаяОрганизация.* КАК Организация}
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ РАЗРЕШЕННЫЕ
	Сотрудники.СтраховойНомерПФР КАК ФизлицоСтраховойНомерПФР,
	Сотрудники.ФизическоеЛицо КАК ФизическоеЛицо,
	ЕСТЬNULL(ФИОФизическихЛицСрезПоследних.Фамилия, Сотрудники.ФизическоеЛицо.Фамилия) КАК Фамилия,
	ЕСТЬNULL(ФИОФизическихЛицСрезПоследних.Имя, Сотрудники.ФизическоеЛицо.Имя) КАК Имя,
	ЕСТЬNULL(ФИОФизическихЛицСрезПоследних.Отчество, Сотрудники.ФизическоеЛицо.Отчество) КАК Отчество,
	ВЫРАЗИТЬ(ВЫБОР
			КОГДА АдресаДляИнформирования.Представление ЕСТЬ НЕ NULL 
				ТОГДА АдресаДляИнформирования.Представление
			КОГДА АдресаФактические.Представление ЕСТЬ НЕ NULL 
				ТОГДА АдресаФактические.Представление
			КОГДА АдресаРегистрации.Представление ЕСТЬ НЕ NULL 
				ТОГДА АдресаРегистрации.Представление
			ИНАЧЕ """"
		КОНЕЦ КАК СТРОКА(300)) КАК АдресДляИнформирования,
	Сотрудники.Организация КАК Организация,
	Сотрудники.НаименованиеПФР КАК НаименованиеПФР
{ВЫБРАТЬ
	ФизлицоСтраховойНомерПФР КАК СтраховойНомерПФР,
	Фамилия,
	Имя,
	Отчество,
	АдресДляИнформирования,
	ФизическоеЛицо.*,
	Организация.*,
	НаименованиеПФР}
ИЗ
	ВТСотрудники КАК Сотрудники
		ЛЕВОЕ СОЕДИНЕНИЕ Справочник.ФизическиеЛица.КонтактнаяИнформация КАК АдресаФактические
		ПО Сотрудники.ФизическоеЛицо = АдресаФактические.Ссылка
			И (АдресаФактические.Вид = ЗНАЧЕНИЕ(Справочник.ВидыКонтактнойИнформации.АдресМестаПроживанияФизическиеЛица))
			И (АдресаФактические.Тип = ЗНАЧЕНИЕ(Перечисление.ТипыКонтактнойИнформации.Адрес))
		ЛЕВОЕ СОЕДИНЕНИЕ Справочник.ФизическиеЛица.КонтактнаяИнформация КАК АдресаРегистрации
		ПО Сотрудники.ФизическоеЛицо = АдресаРегистрации.Ссылка
			И (АдресаРегистрации.Тип = ЗНАЧЕНИЕ(Перечисление.ТипыКонтактнойИнформации.Адрес))
			И (АдресаРегистрации.Вид = ЗНАЧЕНИЕ(Справочник.ВидыКонтактнойИнформации.АдресПоПропискеФизическиеЛица))
		ЛЕВОЕ СОЕДИНЕНИЕ Справочник.ФизическиеЛица.КонтактнаяИнформация КАК АдресаДляИнформирования
		ПО Сотрудники.ФизическоеЛицо = АдресаДляИнформирования.Ссылка
			И (АдресаДляИнформирования.Вид = ЗНАЧЕНИЕ(Справочник.ВидыКонтактнойИнформации.АдресДляИнформированияФизическиеЛица))
			И (АдресаДляИнформирования.Тип = ЗНАЧЕНИЕ(Перечисление.ТипыКонтактнойИнформации.Адрес))
		ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ФИОФизическихЛиц.СрезПоследних(
				&Период,
				ФизическоеЛицо В
					(ВЫБРАТЬ
						Сотрудники.ФизическоеЛицо
					ИЗ
						ВТСотрудники КАК Сотрудники)) КАК ФИОФизическихЛицСрезПоследних
		ПО Сотрудники.ФизическоеЛицо = ФИОФизическихЛицСрезПоследних.ФизическоеЛицо
{ГДЕ
	Сотрудники.Организация.*,
	Сотрудники.ФизическоеЛицо.*}