Ошибка: есть движения по договорам платежных агентов. Отключение флажка запрещено.

Причина возникновения: Возникает при неудачной попытке отключения опции Использовать Агентские Платежи И Разделение Выручки.

Где расположена: Общий модуль - НастройкиУНФ- Функция ОтказСнятьИспользоватьАгентскиеПлатежиИРазделениеВыручки

Что делать: Ниже указан список регистров по котором функция проверяет наличия движений. Проверьте данные регистры на наличие записей препятствующие изменению опции.
 Обратится за помощью к программисту 1С.

Для программиста: Данная функция  обходит список регистров накопления и в случае если есть хотя бы одна запись в указанном списке регистров - выводит данную ошибку. 

Текст процедуры и Список регистров: 

• РегистрНакопления.ДенежныеСредства
• РегистрНакопления.ДенежныеСредстваВКассахККМ
• РегистрНакопления.ДенежныеСредстваКПоступлению

// Проверка на возможность отключения опции ИспользоватьАгентскиеПлатежиИРазделениеВыручки.
//
// Возвращаемое значение:
// 	Строка - текст сообщения если изменение настройки невозможно.
Функция ОтказСнятьИспользоватьАгентскиеПлатежиИРазделениеВыручки() Экспорт
	
	ИменаРегистров = Новый Массив;
	ИменаРегистров.Добавить(НСтр("ru = 'Денежные средства'"));
	ИменаРегистров.Добавить(НСтр("ru = 'Денежные средства в кассах ККМ'"));
	ИменаРегистров.Добавить(НСтр("ru = 'Денежные средства к поступлению'"));
	
	Запрос = Новый Запрос;
	Запрос.Текст =
	"ВЫБРАТЬ ПЕРВЫЕ 1
	|	ДенежныеСредства.Регистратор КАК Регистратор,
	|	0 КАК ИмяРегистра
	|ИЗ
	|	РегистрНакопления.ДенежныеСредства КАК ДенежныеСредства
	|ГДЕ
	|	ДенежныеСредства.ДоговорКонтрагента <> ЗНАЧЕНИЕ(Справочник.ДоговорыКонтрагентов.ПустаяСсылка)
	|
	|ОБЪЕДИНИТЬ ВСЕ
	|
	|ВЫБРАТЬ ПЕРВЫЕ 1
	|	ДенежныеСредстваВКассахККМ.Регистратор,
	|	1
	|ИЗ
	|	РегистрНакопления.ДенежныеСредстваВКассахККМ КАК ДенежныеСредстваВКассахККМ
	|ГДЕ
	|	ДенежныеСредстваВКассахККМ.ДоговорКонтрагента <> ЗНАЧЕНИЕ(Справочник.ДоговорыКонтрагентов.ПустаяСсылка)
	|
	|ОБЪЕДИНИТЬ ВСЕ
	|
	|ВЫБРАТЬ ПЕРВЫЕ 1
	|	ДенежныеСредстваКПоступлению.Регистратор,
	|	2
	|ИЗ
	|	РегистрНакопления.ДенежныеСредстваКПоступлению КАК ДенежныеСредстваКПоступлению
	|ГДЕ
	|	ДенежныеСредстваКПоступлению.ДоговорКонтрагента <> ЗНАЧЕНИЕ(Справочник.ДоговорыКонтрагентов.ПустаяСсылка)";
	
	РезультатЗапроса = Запрос.Выполнить();
	
	Если РезультатЗапроса.Пустой() Тогда
		Возврат "";
	КонецЕсли;
	
	Выборка = РезультатЗапроса.Выбрать();
	
	Если Выборка.Количество() = 1 Тогда
		Шаблон = НСтр("ru = 'В регистре %1'");
	Иначе
		Шаблон = НСтр("ru = 'В регистрах %1'");
	КонецЕсли;
	
	ИмяРегистра = "";
	
	Пока Выборка.Следующий() Цикл
		
		Если ИмяРегистра <> "" Тогда
			ИмяРегистра = ИмяРегистра + ", ";
		КонецЕсли;
		
		ИмяРегистра = ИмяРегистра + ИменаРегистров.Получить(Выборка.ИмяРегистра);
		
	КонецЦикла;
	
	ТекстПодстановки = СтрШаблон(Шаблон, ИмяРегистра);
	
	Возврат СтрШаблон(НСтр("ru = '%1 есть движения по договорам платежных агентов. Отключение флажка запрещено.'"), ТекстПодстановки);
	
КонецФункции