Вид документа не найден в сервисе "1С:Бизнес-сеть"

Причина возникновения: Выполняет проверку наличия новых документов в сервисе, с оповещением пользователю, в случае их появления.  Также, если был передан параметр ГруппаФормы, на форме появляется гиперссылка с уведомлением. При нажатии на оповещение или гиперссылку открывается форма списка входящих документов "1С:Бизнес-сеть".  Вызывается из обработчика события формы ПриСозданииНаСервере.  Обработчик см. БизнесСетьКлиент.ПодобратьДокументыИзСервисаБизнесСеть.

Где расположена: Общий модуль - БизнесСеть- Процедура ПодключитьОповещениеОНовыхДокументахВСервисе

Что делать:  Проверьте все типы подключенных документов в "1С Бизнес-сеть", Обратится за помощью к программисту 1С.

Для программиста: Код в данной процедуре производит поиск подключаемого документа в Списке значений возможных документов для подключения, вот список возможных документов:

• Акт выполненных работ
• Акт передачи прав
• Заказ покупателя
• Заказ поставщику
• Корректировка стоимости
• Товарная накладная
• Отчет о продажах комиссионного товара
• Отчет о списании комиссионного товара
• Прайс-лист
• Счет на оплату
• Коммерческое предложение
• Запрос коммерческих предложений
  

Если будет произведена попытка подключить документ не входящий в данный список - код выдаст данную ошибку.

Текст процедуры: 

Процедура ПодключитьОповещениеОНовыхДокументахВСервисе(Форма, ВидыДокументов, ГруппаФормы = Неопределено) Экспорт
	
	// Добавление служебных реквизитов формы.
	НовыеРеквизитыФормы = Новый Массив;
	
	ИмяРеквизитаИспользованияПодсистемы = БизнесСетьКлиентСервер.ИмяРеквизитаИспользоватьОбменБизнесСеть();
	РеквизитИспользованияПодсистемы = Новый РеквизитФормы(ИмяРеквизитаИспользованияПодсистемы,
		Новый ОписаниеТипов("Булево"));
	НовыеРеквизитыФормы.Добавить(РеквизитИспользованияПодсистемы);
	
	ИмяРеквизитаОперации = БизнесСетьКлиентСервер.ИмяРеквизитаОперацииПодбораДокументовИзСервиса();
	РеквизитОперации = Новый РеквизитФормы(ИмяРеквизитаОперации, Новый ОписаниеТипов("Неопределено"));
	НовыеРеквизитыФормы.Добавить(РеквизитОперации);
	
	ИмяРеквизитаВидаДокумента = БизнесСетьКлиентСервер.ИмяРеквизитаВидаДокументаСервиса();
	РеквизитВидаДокумента = Новый РеквизитФормы(ИмяРеквизитаВидаДокумента,
		Новый ОписаниеТипов("СписокЗначений"));
		
	НовыеРеквизитыФормы.Добавить(РеквизитВидаДокумента);
	
	Форма.ИзменитьРеквизиты(НовыеРеквизитыФормы);
	
	Если Не ПолучитьФункциональнуюОпцию("ИспользоватьОбменБизнесСеть") Тогда
		Возврат;
	КонецЕсли;
	
	Для каждого ВидДокумента Из ВидыДокументов Цикл
		Если ВидыДокументовСервиса().НайтиПоЗначению(ВидДокумента) = Неопределено Тогда
			ТекстСообщения = СтрШаблон(НСтр("ru = 'Вид документа ""%1"" не найден в сервисе ""1С:Бизнес-сеть"".'"), ВидДокумента);
			ВызватьИсключение ТекстСообщения;
		КонецЕсли;
	КонецЦикла;
	
	Если ГруппаФормы <> Неопределено Тогда
		СоздатьГиперссылкуПодбораДокументовИзСервиса(Форма, ГруппаФормы);
	КонецЕсли;
	
	// Создание и запуск фонового задания для актуализации данных.
	ПараметрыОбновления = Новый Структура;
	ПараметрыОбновления.Вставить("ИдентификаторФормы", Форма.УникальныйИдентификатор);
	ПараметрыОбновления.Вставить("ВидыДокументов",     ВидыДокументов);
	
	Операция = ОбновитьИнформациюОНовыхДокументахВСервисеАсинхронно(ПараметрыОбновления);
	
	// Сохранение служебной информации в данных формы.
	Форма[ИмяРеквизитаИспользованияПодсистемы] = Истина;
	Форма[ИмяРеквизитаОперации]                = Операция;
	Форма[ИмяРеквизитаВидаДокумента].ЗагрузитьЗначения(ВидыДокументов);
	
КонецПроцедуры