В строке 1 для алкогольной продукции должно быть указано количество продукции по акцизным маркам - 3, а указано - 4

Причина возникновения: Возникает попытке заполнения акцизных марок Алкогольной продукции.

Где расположена: Общий модуль - АкцизныеМаркиЕГАИС - Процедура ПроверитьЗаполнениеАкцизныхМарокРегистры13

Что делать: проверить равенство количества маркируемой продукции с количеством продукции по акцизным маркам в табличной части документа.  Обратится за помощью к программисту 1С.

Для программиста: Код в данной процедуре проверяет строки табличной части с признаком "Маркируемая продукция" на равенство общего количества и количества продукции по акцизным маркам.

Текст процедуры: 

Процедура ПроверитьЗаполнениеАкцизныхМарокРегистры13(Объект, Отказ, ПроверятьТолькоЕслиЗаполнены, РазрешеноНеУказыватьПартионныеМаркиВСтроке)

	Товары = Объект.Товары.Выгрузить();

	ПараметрыЗаполнения = ПараметрыЗаполненияДанныхАкцизныхМарок(Товары);
	ПараметрыЗаполнения.ЕстьКолонкаТипШтрихкода = Ложь;

	Если Не ПараметрыЗаполнения.ЕстьКолонкаСправка2 Тогда
		Товары.Колонки.Добавить("Справка2", Новый ОписаниеТипов("СправочникСсылка.Справки2ЕГАИС"));
	КонецЕсли;

	АкцизныеМарки = Объект.АкцизныеМарки.Выгрузить();

	ПодготовитьАкцизныеМаркиКЗаполнению(АкцизныеМарки, ПараметрыЗаполнения);

	АлкогольнаяПродукция = СлужебныеДанныеАлкогольнойПродукции(Товары);

	Для Каждого СтрокаТЧ Из АлкогольнаяПродукция Цикл

		Если Не СтрокаТЧ.МаркируемаяПродукция Тогда
			Продолжить;
		КонецЕсли;

		ЗаполнитьДанныеАкцизныхМарокВСтроке(АкцизныеМарки, СтрокаТЧ, ПараметрыЗаполнения);

		Если ПроверятьТолькоЕслиЗаполнены
			И СтрокаТЧ.КоличествоПродукцииПоАкцизнымМаркам = 0 Тогда
			Продолжить;
		КонецЕсли;

		Если РазрешеноНеУказыватьПартионныеМаркиВСтроке
			И СтрокаТЧ.ПомарочныйУчет = Ложь
			И СтрокаТЧ.КоличествоПродукцииПоАкцизнымМаркам = 0 Тогда
			Продолжить;
		КонецЕсли;

		Если СтрокаТЧ.Количество = СтрокаТЧ.КоличествоПродукцииПоАкцизнымМаркам Тогда
			Продолжить;
		КонецЕсли;

		ТекстОшибки = НСтр("ru = 'В строке %1 для алкогольной продукции """"%2"""" должно быть указано количество продукции по акцизным маркам - %3, а указано - %4.'");
		ТекстОшибки = СтрШаблон(
			ТекстОшибки,
			СтрокаТЧ.НомерСтроки,
			СтрокаТЧ.АлкогольнаяПродукция,
			СтрокаТЧ.Количество,
			СтрокаТЧ.КоличествоПродукцииПоАкцизнымМаркам);

		ОбщегоНазначения.СообщитьПользователю(
			ТекстОшибки,
			Объект,
			ОбщегоНазначенияКлиентСервер.ПутьКТабличнойЧасти("Товары", СтрокаТЧ.НомерСтроки, "КоличествоУпаковок"),,
			Отказ);

	КонецЦикла;

КонецПроцедуры