Число цифрами - предмет исчисления прописью

Число цифрами - предмет исчисления прописью
Возвращает текстовое представление числа с единицей измерения в правильном склонении и числе.

Функция ЧислоЦифрамиПредметИсчисленияПрописью(Значение, ПараметрыПредметаИсчисления, ДобавлятьЧислоКРезультату)

Параметры:
Значение - Число - любое целое число.
ПараметрыПредметаИсчисления - Строка - варианты написания единицы измерения для одной,
для двух и для пяти единиц, разделитель - запятая.
ДобавлятьЧислоКРезультату - Булево - при передаче значения Ложь число не будет добавлено к строке.

Возвращаемое значение:
Строка - текстовое представление количества единиц, число записывается цифрами.

Пример:
ЧислоЦифрамиПредметИсчисленияПрописью(23, "минуту,минуты,минут") = "23 минуты";
ЧислоЦифрамиПредметИсчисленияПрописью(15, "минуту,минуты,минут") = "15 минут".

Функция ЧислоЦифрамиПредметИсчисленияПрописью(Знач Значение, Знач ПараметрыПредметаИсчисления,
	Знач ДобавлятьЧислоКРезультату = Истина) Экспорт
	
	Результат = ?(ДобавлятьЧислоКРезультату, Формат(Значение, "ЧН=0") + " ", "");
	ПредставленияПредмета = Новый Массив;
	
	ПараметрыПредметаИсчисления = СтрРазделить(ПараметрыПредметаИсчисления, ",");
	Для Каждого Параметр Из ПараметрыПредметаИсчисления Цикл
		ПредставленияПредмета.Добавить(СокрЛП(Параметр));
	КонецЦикла;
	
	Значение = Значение % 100;
	Если Значение > 20 Тогда
		Значение = Значение % 10;
	КонецЕсли;
	
	Индекс = ?(Значение = 1, 0, ?(Значение > 1 И Значение < 5, 1, 2));
	Результат = Результат + ПредставленияПредмета[Индекс];
	
	Возврат Результат;
	
КонецФункции

БСП / Строковые функции

estart1c от 7-09-2025, 16:47

Число цифрами - предмет исчисления прописью

Похожее

Оставить комментарий