Ошибка: Неизвестный вид упаковки

Причина возникновения: Возникает при неудачной попытке преобразования вида упаковки из типа Строка в тип Значения перечисления. 

Где расположена: Общий модуль - ИнтерфейсИСМПОбщегоНазначения - Функция ВидУпаковки

Что делать: Проверьте указанные виды упаковки в табличной части.
 Обратится за помощью к программисту 1С.

Для программиста: Данная функция  получает на вход вид упакавки с типом Строка, производит сопоставление полученного значения с описанными вариантами упаковки, и в случае если ни одно сопоставление не приведет к положительному результату - выводит данную ошибку. 

Текст процедуры: 

Причина возникновения: Возникает при неудачной попытке преобразования вида упаковки из типа Строка в тип Значения перечисления. 

Где расположена: Общий модуль - ИнтерфейсИСМПОбщегоНазначения - Функция ВидУпаковки

Что делать: Проверьте указанные виды упаковки в табличной части.
 Обратится за помощью к программисту 1С.

Для программиста: Данная функция  получает на вход вид упакавки с типом Строка, производит сопоставление полученного значения с описанными вариантами упаковки, и в случае если ни одно сопоставление не приведет к положительному результату - выводит данную ошибку. 

Текст процедуры: 

// Преобразовывает текстовое представление вида упаковки в значение перечисления.
//
// Параметры:
//  ЗначениеПоиска - Строка - значение для перекодировки
//  ВидПродукции   - ПеречислениеСсылка.ВидыПродукцииИС  - Вид продукции.
//  ЗначениеПоискаДополнительное - Строка
// 
// Возвращаемое значение:
//  ПеречислениеСсылка.ВидыУпаковокИС - вид упаковки.
//
Функция ВидУпаковки(Знач ЗначениеПоиска, ВидПродукции, ЗначениеПоискаДополнительное = Неопределено) Экспорт
	
	Если ТипЗнч(ЗначениеПоиска) = Тип("Строка") Тогда
		
		ЗначениеПоиска = ВРег(ЗначениеПоиска);
		
		Если ОбщегоНазначенияИСКлиентСервер.ЭтоПродукцияМОТП(ВидПродукции) Тогда
			
			Если ЗначениеПоиска = "UNIT" Тогда
				Возврат Перечисления.ВидыУпаковокИС.Потребительская;
			ИначеЕсли ЗначениеПоиска = "GROUP" Или ЗначениеПоискаДополнительное = "GROUP" Тогда
				Возврат Перечисления.ВидыУпаковокИС.Групповая;
			ИначеЕсли ЗначениеПоиска = "SET" Или ЗначениеПоискаДополнительное = "SET" Или ЗначениеПоиска = "PRODUCT_SET" Тогда
				Возврат Перечисления.ВидыУпаковокИС.Набор;
			ИначеЕсли ЗначениеПоиска = "LEVEL1" Тогда
				Возврат Перечисления.ВидыУпаковокИС.Групповая;
			ИначеЕсли СтрНайти(ЗначениеПоиска, "LEVEL") > 0 Тогда
				Возврат Перечисления.ВидыУпаковокИС.Логистическая;
			ИначеЕсли ЗначениеПоиска = "BOX" Тогда
				Возврат Перечисления.ВидыУпаковокИС.Логистическая;
			КонецЕсли;
			
			ВызватьИсключение
				СтрШаблон(
					НСтр("ru = 'Неизвестный вид упаковки: %1'"),
					ЗначениеПоиска);
			
		КонецЕсли;
		
		Если ЗначениеПоиска = "UNIT" Тогда
			Возврат Перечисления.ВидыУпаковокИС.Потребительская;
		ИначеЕсли ЗначениеПоиска = "GROUP" Или ЗначениеПоискаДополнительное = "GROUP" Тогда
			Возврат Перечисления.ВидыУпаковокИС.Групповая;
		ИначеЕсли ЗначениеПоиска = "SET" Или ЗначениеПоискаДополнительное = "SET" Или ЗначениеПоиска = "PRODUCT_SET" Тогда
			Возврат Перечисления.ВидыУпаковокИС.Набор;
		ИначеЕсли СтрНайти(ЗначениеПоиска, "LEVEL") > 0 Тогда
			Возврат Перечисления.ВидыУпаковокИС.Логистическая;
		ИначеЕсли ЗначениеПоиска = "BUNDLE" Или ЗначениеПоиска = "KIT"Тогда
			Возврат Перечисления.ВидыУпаковокИС.Потребительская;
		ИначеЕсли ЗначениеПоиска = "ATK" Тогда
			Возврат Перечисления.ВидыУпаковокИС.АгрегированныйТаможенныйКод;
		ИначеЕсли ЗначениеПоиска = "BOX" Тогда
			Возврат Перечисления.ВидыУпаковокИС.Логистическая;
		КонецЕсли;
		
	Иначе
		
		Если ЗначениеПоиска = Перечисления.ВидыУпаковокИС.Потребительская Тогда
			Возврат "UNIT";
		ИначеЕсли ЗначениеПоиска = Перечисления.ВидыУпаковокИС.Групповая Тогда
			Возврат "GROUP";
		ИначеЕсли ЗначениеПоиска = Перечисления.ВидыУпаковокИС.Набор Тогда
			Возврат "SET";
		ИначеЕсли ЗначениеПоиска = Перечисления.ВидыУпаковокИС.АгрегированныйТаможенныйКод Тогда
			Возврат "АТК";
		ИначеЕсли ЗначениеПоиска = Перечисления.ВидыУпаковокИС.Логистическая Тогда
			Возврат "BOX";
		КонецЕсли;
		
	КонецЕсли;
	
	ВызватьИсключение
		СтрШаблон(
			НСтр("ru = 'Неизвестный вид упаковки: %1'"),
			ЗначениеПоиска);

КонецФункции