Не удалось подключить внешнюю компоненту на сервере по причине: Подключение на сервере не из макета запрещено

Причина возникновения: Возникает при попытке подключить компоненту, выполненную по технологии Native API и COM.
Внимание! Компонента должна храниться в макете конфигурации в виде ZIP-архива.

Где расположена: Общий модуль - ВнешниеКомпонентыБПО- Процедура ПодключитьКомпонентуИзМакета

Что делать:  Проверьте что внешняя компонента находится в ZIP-архиве и расположена в макете. Обратится за помощью к программисту 1С.

Для программиста: Код в данной процедуре производит попытку подключения компоненты распложённой в макете.

Текст процедуры: 

Функция ПодключитьКомпонентуИзМакета(Знач Идентификатор, Знач ПолноеИмяМакета, Знач Изолированно = Ложь) Экспорт

	Если ОбщегоНазначенияБПО.ИспользуетсяБСП() Тогда
		
		// Вызов БСП
		ОбщегоНазначенияМодуль = ОбщегоНазначенияБПО.ОбщийМодуль("ОбщегоНазначения");
		Возврат ОбщегоНазначенияМодуль.ПодключитьКомпонентуИзМакета(Идентификатор, ПолноеИмяМакета, Изолированно);
		// Конец Вызов БСП
		
	Иначе
		ПодключаемыйМодуль = Неопределено;
		
		Если Не МакетСуществует(ПолноеИмяМакета) Тогда 
			ВызватьИсключение СтрШаблон(
				НСтр("ru = 'Не удалось подключить внешнюю компоненту ""%1"" на сервере
				           |из %2
				           |по причине:
				           |Подключение на сервере не из макета запрещено'"),
				Идентификатор,
				ПолноеИмяМакета);
		КонецЕсли;
		
		Местоположение = ПолноеИмяМакета;
		СимволическоеИмя = Идентификатор + "SymbolicName";
		
		#Если Не МобильноеПриложениеСервер Тогда
		Результат = ПодключитьВнешнююКомпоненту(Местоположение, СимволическоеИмя, , ТипПодключенияКомпоненты(Изолированно));
		#Иначе
		Результат = ПодключитьВнешнююКомпоненту(Местоположение, СимволическоеИмя);
		#КонецЕсли
	
		Если Результат Тогда
			
			Попытка
				ПодключаемыйМодуль = Новый("AddIn." + СимволическоеИмя + "." + Идентификатор);
				Если ПодключаемыйМодуль = Неопределено Тогда 
					ВызватьИсключение НСтр("ru = 'Оператор Новый вернул Неопределено'");
				КонецЕсли;
			Исключение
				ПодключаемыйМодуль = Неопределено;
				ТекстОшибки = ОбработкаОшибок.КраткоеПредставлениеОшибки(ИнформацияОбОшибке());
			КонецПопытки;
			
			Если ПодключаемыйМодуль = Неопределено Тогда
				
				ТекстОшибки = СтрШаблон(
					НСтр("ru = 'Не удалось создать объект внешней компоненты ""%1"", подключенной на сервере
					           |из макета ""%2"",
					           |по причине:
					           |%3'"),
					Идентификатор,
					Местоположение,
					ТекстОшибки);
				ОбщегоНазначенияБПО.ЗаписатьОшибкуВЖурналРегистрации(
					НСтр("ru = 'Подключение внешней компоненты на сервере'", ОбщегоНазначенияБПО.КодОсновногоЯзыка()),
					ТекстОшибки);
			КонецЕсли;
			
		Иначе
			
			ТекстОшибки = СтрШаблон(
				НСтр("ru = 'Не удалось подключить внешнюю компоненту ""%1"" на сервере
				           |из макета ""%2""
				           |по причине:
				           |Платформа вернула Ложь при подключении внешней компоненты.'"),
				Идентификатор,
				Местоположение);
			ОбщегоНазначенияБПО.ЗаписатьОшибкуВЖурналРегистрации(
				НСтр("ru = 'Подключение внешней компоненты на сервере'", ОбщегоНазначенияБПО.КодОсновногоЯзыка()),
				ТекстОшибки);
		КонецЕсли;
		
		Возврат ПодключаемыйМодуль;
	КонецЕсли;
	
КонецФункции